[Conta Azul] Como tratar o relatório Extrato de Movimentações

let
  Fonte = Fonte_Dados, //Planilhas com os extratos de movimentações
  Transforma = Table.UnpivotOtherColumns( //Transforma as colunas com categorias e centro de custos em linhas
    Fonte, 
    {
      "Observações", 
      "Data prevista", 
      "Data original de vencimento", 
      "Data de competência", 
      "Taxas (R$)", 
      "Desconto (R$)", 
      "Multa (R$)", 
      "Juros (R$)", 
      "Valor original (R$)", 
      "Situação", 
      "Saldo conta (R$)", 
      "Valor (R$)", 
      "Forma de pgto/recbto", 
      "Conta bancária", 
      "Tipo da operação", 
      "Agendado", 
      "Descrição", 
      "Recorrência", 
      "Nome do fornecedor/cliente", 
      "Identificador do fornecedor/cliente", 
      "Data movimento"
    }, 
    "Atributo", 
    "Valor"
  ), 
  Indice_1 = Table.AddIndexColumn(Transforma, "indice", 0, 1, Int64.Type), // Adiciona uma coluna de ÍNDICE para realizar o tratamento das categorias e centros de custos
  Trata_Valor = Table.AddColumn( //Adiciona uma coluna para realizar o tratamento dos valores e textos => Importante para validação das colunas
    Indice_1, 
    "transforma_valor", 
    each try Number.FromText([Valor]) otherwise [Valor]
  ), 
  Verifica_Valor = Table.AddColumn(Trata_Valor, "é_numero", each [transforma_valor] is number),  //Verifica se a coluna criada anteriormente é número ou texto => Importante para entender como faremos a classificação das categorias e centros de custos
  Categoria = Table.AddColumn( //Adiciona uma coluna com a informação da categoria ao lado do valor do lançamento
    Verifica_Valor, 
    "Categoria", 
    each 
        // Se o valor da coluna [Atributo] inicia com "Valor na Categoria " pegará os dados da linha anterior da coluna [Valor]
      if [é_numero] and Text.Start([Atributo], 19) = "Valor na Categoria " then
        Verifica_Valor[Valor]{[indice] - 1} 
      else
        null
  ), 
  Centro_de_custo = Table.AddColumn(
    Categoria, 
    "Centro de Custo", 
    each 
        // Se o valor da coluna [Atributo] inicia com "Valor no Centro de Custo " pegará os dados da linha anterior da coluna [Valor]
      if [é_numero] and Text.Start([Atributo], 25) = "Valor no Centro de Custo " then
        Verifica_Valor[Valor]{[indice] - 1}
      else
        null
  ), 
  FiltraNumeros = Table.SelectRows(Centro_de_custo, each ([é_numero] = true)), // Filtra a coluna [é_numero] se for verdadeiro para eliminar as linhas sem valores lançados 
  Indice_2 = Table.AddIndexColumn(FiltraNumeros, "indice_filtro", 0, 1, Int64.Type), // Adiciona novo índice para realizar mais um filtro por causa do detalhamento das Categorias e dos Centros de Custos
  Filtro_Detalhes = Table.AddColumn(
    Indice_2, // Adiciona nova coluna para fazer novo filtro e remover os valores "cheios" sem o rateio das categorias e centros de custos
    "Filtro", 
    each try
      (
        Indice_2[Categoria]{[indice_filtro] + 1}
          is null and Indice_2[Centro de Custo]{[indice_filtro] + 1}
          <> null
      )
        and ([Categoria] <> null and [Centro de Custo] is null)
    otherwise
      false
  ), 
  Preenche_Null = Table.FillDown(Filtro_Detalhes, {"Categoria"}), // Preenche para baixa a coluna categoria para trazer
  Filtra_Linhas = Table.SelectRows(Preenche_Null, each ([Filtro] = false)), // Filtra todas as linhas com valores "cheios"
  Remove_Colunas = Table.SelectColumns( // Seleciona colunas que serão necessárias para análise
    Filtra_Linhas,  
    { // Você pode remover aqui as colunas que não trabalhará
      "Data movimento", 
      "Identificador do fornecedor/cliente", 
      "Nome do fornecedor/cliente", 
      "Recorrência", 
      "Descrição", 
      "Agendado", 
      "Tipo da operação", 
      "Conta bancária", 
      "Forma de pgto/recbto", 
      "Valor (R$)", 
      "Saldo conta (R$)", 
      "Situação", 
      "Valor original (R$)", 
      "Juros (R$)", 
      "Multa (R$)", 
      "Desconto (R$)", 
      "Taxas (R$)", 
      "Data de competência", 
      "Data original de vencimento", 
      "Data prevista", 
      "Observações", 
      "Valor", 
      "Categoria", 
      "Centro de Custo"
    }
  ), 
  Null_Preenchido = Table.ReplaceValue( // Altera os valores nulos do centros de custo para "Não informado"
    Remove_Colunas, 
    null, 
    "Não informado", 
    Replacer.ReplaceValue, 
    {"Centro de Custo"}
  ), 
  Tipo_Alterado = Table.TransformColumnTypes( // Altera o tipo dos dados
    Null_Preenchido, 
    {{"Valor", type number}, {"Categoria", type text}, {"Centro de Custo", type text}}
  )
in
  Tipo_Alterado